The Chatterbox

// 04 The Chatterbox
// The Maker's Book of Origins, chapter 04. Upload it, then turn back to the book.
// makernest.com/origins/04
// MakerNest Origins is a brand of Innointel Global Private Limited.

#include <MakerNestOrigins.h>

bool alarm = false;

void setup() {
  machine.begin(4, "04|CHATTER|BOX");
  machine.homeShows(SHOW_A | SHOW_LINE);     // the number, and START and STOP under it
  machine.useScreen(SCR_COLD_LINE);          // START
  machine.useScreen(SCR_STOP_AT);            // STOP AT
  machine.useScreen(SCR_NORMAL_COLOUR);
  machine.useScreen(SCR_WHEN_COLD);
  machine.useScreen(SCR_TEST);
}

void loop() {
  machine.update();
  if (machine.settings.coldLine == NOT_SET) { machine.ringNormal(); return; }
  int start = machine.settings.coldLine;
  int stop = (machine.settings.stopAt == NOT_SET) ? start : machine.settings.stopAt;
  float t = machine.temperatureA();

  // Two instructions, not one.
  if (!alarm && t < start) alarm = true;     // start
  if (alarm && t >= stop) alarm = false;     // stop
  // With STOP AT the same as START, every tiny wobble across the line flips it. Give it a gap.

  uint8_t w = machine.settings.whenCold;
  if (alarm && (w == WHEN_RING || w == WHEN_BOTH)) machine.ring(RED); else machine.ringNormal();
  if (w == WHEN_ALWAYS) machine.buzzer(true);
  else { machine.buzzer(false); machine.buzzerBeep(alarm && (w == WHEN_BUZZER || w == WHEN_BOTH)); }
}

// MakerNest Origins · bench 04 · a light that waits before it changes its mind
// Same circuit as bench 02. Two lines instead of one, and a wait.
// The LED comes on below ON_BELOW and only goes off again above OFF_ABOVE.
// Either change has to stay true for WAIT milliseconds before it happens.

const int SENSOR_PIN = A0;
const int LED_PIN = 12;
const int ON_BELOW = 300;
const int OFF_ABOVE = 400;   // the gap between the two lines stops it chattering
const unsigned long WAIT = 2000;

bool ledOn = false;
unsigned long wantedSince = 0;   // when the light first asked for a change

void setup() {
  pinMode(LED_PIN, OUTPUT);
  Serial.begin(9600);
}

void loop() {
  int light = analogRead(SENSOR_PIN);
  Serial.println(light);

  bool wantChange = (!ledOn && light < ON_BELOW) || (ledOn && light > OFF_ABOVE);
  if (!wantChange) {
    wantedSince = 0;                       // the light changed its mind: start again
  } else if (wantedSince == 0) {
    wantedSince = millis();                // the light has asked: start the clock
  } else if (millis() - wantedSince >= WAIT) {
    ledOn = !ledOn;                        // it asked for long enough: change
    digitalWrite(LED_PIN, ledOn ? HIGH : LOW);
    wantedSince = 0;
  }
  delay(100);
}